***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Aug 09, 2019                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.subckt BZX84B3 A K 
.param
+vc0 = 1.4996e-10	 vc1 = 9.883e-9 	 vc2 = 2.000e0		 vc3 = 7.551e-7		 vc4 = 7.700e0
+tc1 = 3.991e-2		 tc2 = 7.721e-3		 tc3 = 3.191e-3		 tc4 = 1.001e-4	   
.func irpwr(v) {(vc0+vc1*v**vc2)*(1.0+tc1*(temp-25)*exp(tc2*(temp-25)))+(vc3*v**vc4)*(1.0+tc3*(temp-25)*exp(tc4*(temp-25)))}
d1 A K zener
g1 K A value = {irpwr(v(K,A))}
.model zener d
***** flag parameter *****
+level = 1
***** dc model parameter *****
+ is = 7.976e-16 	   n = 1.008		  rs = 4.819e-1		 ikf = 1.252e-1
+ibv = 1e-3		 nbv = 5.0		  bv = 3
***** capacitance parameter *****
+cjo = 1.902e-10	   m = 3.312e-1		  vj = 7.466e-1
+ fc = 0.5
***** temperature coefficient *****
+tnom = 25		  eg = 1.075		 xti = 3
+trs1 = 9.016e-6	trs2 = 1.234e-5		tikf = 1e-3			
+tbv1 = -6.595e-4	tbv2 = -0.908e-6
.ends BZX84B3
*$
